BRILLE HeadPlay HD FPV Headset

#define P_VOLTAGE A3

#define P_BEEP 2
#define P_REC 3

#define WARN_CELL 330
#define ALARM_CELL 320
#define BEEP_LENGTH 200
#define BEEP_INTERVAL 5000

long volts = 0;
long voltage = 0;
int cells = 3;
boolean recording = false;

void setup() {
  pinMode(P_BEEP, OUTPUT);
  pinMode(LED_BUILTIN, OUTPUT);

  pinMode(P_REC, OUTPUT);

  Serial.begin(115200);

  delay(1000);
  
  voltage = readVolts();

  // over 9V -> 3 Cells, else 2
  if (voltage > 900) {
    cells = 3;
  } else {
    cells = 2;
  }

  Serial.print("Cells: ");Serial.println(cells);

  // beep for each found cell.
  for (int i=0; i < cells; i++){
    beep();
    delay(BEEP_LENGTH*4);
  }

  delay(BEEP_INTERVAL*2);

  // start recording
  rec();
}

void loop() {
  
  voltage = readVolts();

  if ( (voltage/cells) < ALARM_CELL) {
    // ALARM BAT LOW
    beep();
    delay(BEEP_LENGTH);
    beep();
    delay(BEEP_LENGTH);
    beep();
    delay(BEEP_INTERVAL/2);
    if (recording) { // stop recording on bat low.
      rec();
    }
    digitalWrite(LED_BUILTIN, HIGH);
  } else if ( (voltage/cells) < WARN_CELL) {
    beep();
    delay(BEEP_INTERVAL);
  } else {
    digitalWrite(LED_BUILTIN, LOW);
    delay(BEEP_INTERVAL);
  }

}

int readVolts() {
  volts=0;
  for (int i=0; i < 10; i++){
    volts += analogRead(P_VOLTAGE);  
  }
  volts = volts/10;
  volts = map(volts, 0, 1024, 0, 2000); // Voltage Divider 1/4 -> 10k/30k can read up to 20 Volts

  Serial.println(volts);
  
  return volts;
}

void beep() {
  digitalWrite(P_BEEP, HIGH);
  digitalWrite(LED_BUILTIN, HIGH);
  delay(BEEP_LENGTH);
  digitalWrite(P_BEEP, LOW);
  digitalWrite(LED_BUILTIN, LOW);
}

void rec() {
  digitalWrite(P_REC, HIGH);
  delay(1000);
  digitalWrite(P_REC, LOW);
  recording = !recording;
}